Appendice B la storia di "Heidi"
================================



Heidi nella Foresta è il nostro primo - e più semplice - gioco. L'abbiamo descritto in tre capitoli:
"Heidi: il nostro primo gioco in inform" nel terzo capitolo, "Riepiloghiamo le basi" nel quarto capitolo e "Rivediamo Heidi" nel quinto capitolo.
Qui riportiamo una trascrizione di una partita, e quindi il file sorgente originale in tutta la sua estensione.




Transcrizione di una partita
****************************



Heidi
Un semplice esempio in Inform
di Roger Firth e Sonja Kesserich.
Versione 1 / Numero di Serie 030701 / Inform v6.21 Libreria 6/10
Infit Versione 2.1 / Numero di serie 030106 / (c) 2003 by Giovanni Riccardi SD

Di fronte a una baita
Ti trovi davanti a una baita. Verso est si stende la foresta.

>LUNGO

Heidi è ora in modalità "completa", che da descrizioni lunghe per tutti i luoghi (anche se già visitati).

>EST

Nel folto del bosco
Attraverso la folta vegetazione, ti pare di scorgere un edificio verso ovest. Un sentiero porta verso nord-est.

Puoi vedere un uccellino qui.

>ESAMINA L'UCCELLINO
Troppo giovane per saper volare, il passerotto pigola inerme.

>PRENDI PASSEROTTO
Preso.

>NE

Una radura nella foresta
Un alto sicomoro si erge al centro di questa radura. Il sentiero si inoltra tra gli alberi, serso sud-ovest.

Puoi vedere un nido di uccelli (che è vuoto) qui.

>METTI UCCELLO NEL NIDO
Hai messo l'uccellino dentro il nido di uccelli.

>ESAMINA IL NIDO
Il nido e' fatto di rametti e sterpi intrecciati.

>PRENDI NIDO
Preso.

>SU

In cima all'albero
Ti tieni precariamente appesa al tronco.

Puoi vedere un ramo largo e robusto qui.

>METTI IL NIDO SUL RAMO
Hai messo il nido di uccelli sopra il ramo largo e robusto.


    *** Hai vinto ***


In questa partita hai totalizzato 0 punti su 0 possibili, in 10 turni.

Vuoi RICOMINCIARE, CARICARE una partita salvata o USCIRE ?

>USCIRE 





Codice sorgente del gioco - versione originale
**********************************************



!===============================================================================
Constant Story "Heidi";
Constant Headline
            "^Semplice esempio in Inform
             ^di Roger Firth e Sonja Kesserich.^";
             ! Traduzione di Paolo Lucchesi
Constant MAX_CARRIED 1;

Include "Parser";
Include "VerbLib";
Include "Replace";

!===============================================================================
! Oggetti di gioco

Object  davanti_baita "Di fronte a una baita"
  with  description
            "Ti trovi davanti a una baita. Verso est si stende la foresta.",
        e_to foresta,
  has   light;

Object  foresta "Nel folto del bosco"
  with  description
            "Attraverso la folta vegetazione, ti pare di scorgere un edificio
             verso ovest. Un sentiero porta verso nord-est.",
        w_to davanti_baita,
        ne_to radura,
  has   light;

Object  uccello "uccellino" foresta
  with  description "Troppo giovane per saper volare, il passerotto pigola inerme.",
        name 'uccello' 'uccellino' 'passero' 'passerotto' 'volatile',
  has   ;

Object  radura "Una radura nella foresta"
  with  description
            "Un alto sicomoro si erge al centro di questa radura.
             Il sentiero si inoltra tra gli alberi, serso sud-ovest.",
        sw_to foresta,
        u_to sull_albero,
  has   light;

Object  nido "nido di uccelli" radura
  with  description "Il nido e' fatto di rametti e sterpi intrecciati.",
        name 'nido' 'rametti' 'sterpi',
  has   container open;

Object  albero "albero di sicomoro" radura
  with  description
            "Fieramente alto nel mezzo della radura,
             l'albero sembra molto facile da scalare.",
        name 'albero' 'sicomoro' 'tronco',
  has   scenery;

Object  sull_albero "In cima all'albero"
  with  description "Ti tieni precariamente appesa al tronco.",
        d_to radura,
  has   light;

Object  ramo "ramo largo e robusto" sull_albero
  with  description "E' abbastanza largo da sostenere un'oggetto.",
        name 'ramo' 'largo' 'robusto',
        each_turn [; if (nido in ramo) deadflag = 2; ],
  has   static supporter;

!===============================================================================
! Entry point routines

[ Initialise; location = davanti_baita; ];

!===============================================================================
! Grammatica

Include "ItalianG";

!===============================================================================






Codice sorgente del gioco rivisto
*********************************




!===============================================================================
Constant Story "Heidi";
Constant Headline
            "^Semplice esempio in Inform
             ^di Roger Firth e Sonja Kesserich.^";
             ! Traduzione di Paolo Lucchesi
Constant MAX_CARRIED 1;

Include "Parser";
Include "VerbLib";
Include "Replace";

!===============================================================================
! Oggetti

Object  davanti_baita "Di fronte a una baita"
  with  description
            "Ti trovi davanti a una baita. Verso est si stende la foresta.",
        e_to foresta,
        in_to "E' una stupenda giornata per una passeggiata nella foresta.",
        cant_go "L'unico sentiero conduce ad est.",
  has   light;

Object  baita "piccola baita" davanti_baita
  with  description "E' piccola e semplice, ma qui tu sei felice.",
        name 'piccola' 'baita' 'case' 'capanna' 'rifugio',
        before [; Enter:
            print_ret "E' una stupenda giornata per una passeggiata nella foresta.";
        ],
  has   scenery female;

Object  foresta "Nel folto del bosco"
  with  description
            "Attraverso la folta vegetazione, ti pare di scorgere un edificio
             verso ovest. Un sentiero porta verso nord-est.",
        w_to davanti_baita,
        ne_to radura,
  has   light;

Object  uccello "uccellino" foresta
  with  description "Troppo giovane per saper volare, il passerotto pigola inerme.",
        name 'uccello' 'uccellino' 'passero' 'passerotto' 'volatile',
        before [; Listen:
            print "Sembra spaventato e bisognoso d'aiuto.^";
            return true;
        ],        
  has   ;

Object  radura "Una radura nella foresta"
  with  description
            "Un alto sicomoro si erge al centro di questa radura.
             Il sentiero si inoltra tra gli alberi, serso sud-ovest.",
        sw_to foresta,
        u_to sull_albero,
  has   light;

Object  nido "nido di uccelli" radura
  with  description "Il nido e' fatto di rametti e sterpi intrecciati.",
        name 'nido' 'rametti' 'sterpi',
  has   container open;

Object  albero "albero di sicomoro" radura
  with  description
            "Fieramente alto nel mezzo della radura,
             l'albero sembra molto facile da scalare.",
        name 'albero' 'sicomoro' 'tronco',
        before [; Climb:
            PlayerTo(sull_albero);
            return true;
        ],        
  has   scenery;

Object  sull_albero "In cima all'albero"
  with  description "Ti tieni precariamente appesa al tronco.",
        d_to radura,
        after [; Drop:
            move noun to radura;
            return false;
        ],        
  has   light;

Object  ramo "ramo largo e robusto" sull_albero
  with  description "E' abbastanza largo da sostenere un'oggetto.",
        name 'ramo' 'largo' 'robusto',
        each_turn [; if (uccello in nido && nido in ramo) deadflag = 2; ],
  has   static supporter;

!===============================================================================
! Entry point routines

[ Initialise; location = davanti_baita; ];

!===============================================================================
! Grammatica

Include "ItalianG";

!===============================================================================